@echo off

rem -------------------------------------------------
rem ICMから三角柱変換に戻すBAT Ver02.00
rem
rem 対象機種 D701(A1), D703(A3), D1005(A4)
rem
rem Ver02.00から64bitOSに対応
rem -------------------------------------------------

rem OSの判定
for /f "skip=1 tokens=3*" %%I in (
 'reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v "PROCESSOR_ARCHITECTURE"'
) do set PA=%%I

rem OSにあわせたレジストリの場所を設定
if "%PA%" == "x86" (
 rem 32bit
 set regNK="HKLM\SOFTWARE\Noritsukoki\Profile Data\CurrentVersion\InstallInfo"
) else if "%PA%" == "AMD64" (
 rem 64bit
 set regNK="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Noritsukoki\Profile Data\CurrentVersion\InstallInfo"
) else if "%PA%" == "IA64" (
 rem 64bit
 set regNK="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Noritsukoki\Profile Data\CurrentVersion\InstallInfo"
) else (
 rem 不明
 set regNK="HKLM\SOFTWARE\Noritsukoki\Profile Data\CurrentVersion\InstallInfo"
)

rem レジストリからpfフォルダの場所を取得
for /f "skip=1 tokens=3*" %%A in (
 'reg query %regNK% /v "Path"'
) do set pf=%%A

rem pfフォルダのパスの最後の\がないときは足す
if not "%pf:~-1%" == "\" (
 set pf=%pf%\
)

rem pfフォルダがない時は終了
if not exist %pf%nul goto END

rem PRN_V02_01_DIRフォルダを消す
rem D701(A1)
if exist %pf%A1\PRN_V02_01_DIR/nul (
 RMDIR /S /Q %pf%A1\PRN_V02_01_DIR
)

rem D703(A3)
if exist %pf%A3\PRN_V02_01_DIR/nul (
 RMDIR /S /Q %pf%\A3\PRN_V02_01_DIR
)

rem D1005(A4)
if exist %pf%A4\PRN_V02_01_DIR/nul (
 RMDIR /S /Q %pf%\A4\PRN_V02_01_DIR
)


rem PRN_V02_01_DIRが消えていればバージョン名を書き換える
if exist %pf%A1\PRN_V02_01_DIR/nul goto END
if exist %pf%A3\PRN_V02_01_DIR/nul goto END
if exist %pf%A4\PRN_V02_01_DIR/nul goto END

rem バージョン名の取得
for /f "skip=1 tokens=3*" %%B in (
 'reg query %regNK% /v "Version"'
) do set pfver=%%B %%C

rem バージョン名の変更
reg add %regNK% ^
 /v "Version" /t REG_SZ /f /d "T%pfver:~1%"

rem 終了
:END
pause